Recently, I have been using GMail as my primary e-mail client. It’s simple to use, lightweight, fast and powerful. One feature I particularly like is the Archive button, which lets me clear messages out of my inbox with a single click. Instead of letting e-mails clutter up my inbox just in case I need them again, I can archive them as soon as I’ve read them. Fewer items in my inbox makes it easier to focus and prioritize tasks, which in turn makes me more productive.

In the high-pressure environment at work, where I frequently receive up to a hundred or so e-mails a day, everything I can do to make my life easier helps. Here is how I added an Archive button to Microsoft Outlook:

1. Make a new folder in Outlook called Archive.
2. Open the macro editor under Tools > Macros > Visual Basic Editor.
3. Open ThisOutlookSession under Project1 in the Project Explorer window at the left side of the screen.
4. Paste the following code:

   Option Explicit
   
   Public Sub ArchiveSelectedItems()
       MoveSelectedItemsToFolder "Archive"
   End Sub
   
   Private Sub MoveSelectedItemsToFolder(FolderName As String)
       On Error GoTo ErrorHandler
   
       Dim Namespace As Outlook.Namespace
       Set Namespace = Application.GetNamespace("MAPI")
   
       Dim Inbox As Outlook.MAPIFolder
       Set Inbox = Namespace.GetDefaultFolder(olFolderInbox)
   
       Dim Folder As Outlook.MAPIFolder
       Set Folder = Inbox.Folders(FolderName)
   
       If Folder Is Nothing Then
           MsgBox "The '" & FolderName & "' folder doesn't exist!", _
               vbOKOnly + vbExclamation, "Invalid Folder"
       End If
   
       Dim Item As Object
       For Each Item In Application.ActiveExplorer.Selection
           If Item.UnRead Then Item.UnRead = False
           Item.Move Folder
       Next
   
       Exit Sub
   
   ErrorHandler:
       MsgBox Error(Err)
   
   End Sub

5. Save and close the editor.

Now the archive macro has been created. Let’s add a button that will trigger it:

1. Click on View > Toolbars > Customize, and select the Commands tab.
2. Scroll down to the Macros category.
3. Drag the Project1.ThisOutlookSession.ArchiveSelected command to a toolbar.
4. Right-click on your new button, and rename it to Archive Selected. Set it to display Text Only.
5. Click Close.

All done!